*******************************************************************************
* Copyright (C) Maxim Integrated Products, Inc., All rights Reserved.
*
* This software is protected by copyright laws of the United States and
* of foreign countries. This material may also be protected by patent laws
* and technology transfer regulations of the United States and of foreign
* countries. This software is furnished under a license agreement and/or a
* nondisclosure agreement and may only be used or reproduced in accordance
* with the terms of those agreements. Dissemination of this information to
* any party or parties not specified in the license agreement and/or
* nondisclosure agreement is expressly prohibited.
* The above copyright notice and this permission notice shall be included
* in all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
* OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
* MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
* IN NO EVENT SHALL MAXIM INTEGRATED BE LIABLE FOR ANY CLAIM, DAMAGES
* OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
* ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
* OTHER DEALINGS IN THE SOFTWARE.
*
* Except as contained in this notice, the name of Maxim Integrated
* Products, Inc. shall not be used except as stated in the Maxim Integrated
* Products, Inc. Branding Policy.
*
* The mere transfer of this software does not imply any licenses
* of trade secrets, proprietary technology, copyrights, patents,
* trademarks, maskwork rights, or any other form of intellectual
* property whatsoever. Maxim Integrated Products, Inc. retains all
* ownership rights.
*******************************************************************************
.SUBCKT MAX40070 IP GND IM OUT VDD REF HYST EN
*                 |  |   |  |   |   |   |   |
*                 |  |   |  |   |   |   |   Device Enable (Active Low)
*                 |  |   |  |   |   |   Hysteresis Input
*                 |  |   |  |   |   Reference Output Voltage
*                 |  |   |  |   Positive Supply
*                 |  |   |  Open-Drain Output
*                 |  |   Inverting Input
*                 |  Ground
*                High-Voltage Non-inverting input
*
* Date of model creation: 08-19-2021
* Revision History:
*                v1.0 - Initial Release. JY
* Supported:
*      Typical performance for temperature range (-40 to 125) degrees Celsius
*      DC, AC, and Transient.
*      Most specs, including: VDD Supply voltage range, Supply current, power-up time, input common-mode voltage Range, input offset voltage, input offset drift, input *hysteresis,PSRR,CMRR,VOL,Propagation Delay;
*      Temperature effects for Output Voltage Drift, Iquiescent
* Not Supported:
*      Temperature effects for Output Voltage Drift, Iquiescent
*      Long-Term Stability
*      Thermal hysteresis
*	   Noise
* Known Discrepancies in Model vs. Datasheet:
*      Output Noise Voltage: not modeled,the value is much smaller than actual device
*

X_LM IP IM OUT VDD GND REF HYST EN COMP
.ENDS MAX40070

*?@ Start SIMPLIS Encryption $$WC_SIMPLIS_ENCRYPT_TAG$$
****************
.SUBCKT COMP IP 23 out VDD 18 REF HYST EN1
Ren en2 en3 100
Cen en3 0 2u
Een2 en2 0 value={if(V(en1)>0.75,0,1)}
Een en 0 value={if(V(en3)>0.75,1,0)}
So1 out out1 sh 0 smod2
So2 out1 out2 47 0 smod3
Vo3 out2 out3 0
Eo3 out3 0 value={I(vo3)*10}
Eip 55 0 value={V(ip)/11}
Rip ip 0 6.6meg
Iim 23 0 0.1n
Cin ip 0 0.15p
Eref refi 0 value={1.6+0.16m*V(vdd)-0.01k*I(vref)}
Vref refi ref 0
Ien en1 0 0.1n
Ren1 en 0 10k
E500 10 18 500 18 1
VS1 10 11 0V    
RNC1 11 12 200K
RNC2 11 13 200K
IPBIAS 11 14 260NA
RBIAS 14 25 10G
RPE1 15 14 10M
RPE2 16 14 10M
Q1 20 22 15 QPA
Q2 21 23 16 QPB
Q3 12 22 19 QNA
Q4 13 23 24 QNB
RNE1 19 17 10M
RNE2 24 17 10M
INBIAS 17 18 260NA
RPC1 20 18 200K
RPC2 21 18 200K
FSUP 18 10 VS1 1 
EOS 29 30 value={175u*V(vdd)-1.4M}
EPSRR 30 67 vdd 18 2.8721u
ECMRR 67 55 14 18 0.5M
*****************
EG 25 18 10 18 0.5 
*****************
*INPUT REFERED HYSTERISIS
Ihyst 0 hyst 3u
GH 25 26 21 20 1
RH 25 26 1MEG
CH 26 27 10P
DL1 26 27 DA  
VL1 27 25 1V
DL2 28 26 DA
VL2 25 28 1V
Eh1 h1 0 value={(V(hyst)-V(23))/3}
EHYST 22 29 value={(2.5m+V(h1))*(V(26)-V(25))}
*****************
*PROPAGATION DELAY 
GPS1 25 69 26 25 10M
RPS1 69 25 1MEG
DPS1 69 70 DA
VPS1 70 71 0.35
EPS1 71 25 66 65 40M 
DPS2 72 69 DA
VPS2 25 72 0.68V
GPS2 25 33 69 25 2916.4U
CS3 69 25 0.1P
CP 33 25 6N
DPS3 31 33 DA
VPS3 25 31 1V
DPS4 33 32 DA
VPS4 32 25 1V
********* 
EP2 34 25 33 25 1
EHP 35 34 37 25 283M
RP3 35 36 1K
VIS1 36 25 0V
FP1 25 37 VIS1 10
RP4 37 25 1MEG
DP3 37 38 DA
DP4 39 37 DA
VP1 38 25 1V
VP2 25 39 1V
CP1 37 25 10P
*****************
*OUTPUT VOLTAGE LIMITS
GOUT 25 40 37 25 1M
ROUT 40 25 5000
DOL1 40 200 DA
DOL2 900 40 DA
EOL1 41 25 10 18 0.5 
EOL2 25 42 10 18 0.5
COL 40 25 1P
V90 900 0 665m
*****************
*RISE AND FALL TIMES
EOUT1 43 25 40 25 1
DT1 43 44 DA
DT2 45 43 DA
RT1 44 46 1K
RT2 45 46 1K
CT1 46 25 1P
*****************
*OUTPUT CURRENT LIMIT
EOUT2 47 25 46 25 1
ROUT2 47 202 15
V01 48 51 0
Hs1 41 200 VHs1 122
Hs2 42 201 VHs2 352
VHs1 202 203 0
VHs2 203 401 0
Eoutleak 402 25 47 25 -1
Soutleak 401 48 402 25 smod1
*SUPPLY VOLTAGE DEPENDENT CURRENT LIMIT 
EVR 52 25 10 18 1
RVR 52 53 1MEG
DVR 53 54 DA
VVR 54 25 1.8V
*****************
*SUPPLY CURRENT
VIS2 51 56 0V
FSUP1 25 57 VIS2 1.28
DSUP1 25 57 DB
DSUP2 57 58 DB 
VIS3 58 25 0V
FSUP2 10 18 VIS3 0.00035
Gdd vdd 18 value={(15.6u+54n*V(vdd))*V(sh)+0.4u*V(on2)}
Edd 500 0 table {V(vdd)} = (0,0) (3.1,3.1) (36,5.5)
Eon on 0 value={if(V(500)>3.09,1,0)}
Ron on on1 100
Con on1 0 3.6u
Eon3 on2 0 value={if(V(on1)>0.75,1,0)}
Esh1 sh1 0 value={if(V(en)>0.75,1,0)}
Esh sh 0 value={V(on2)*V(sh1)}
*****************
*SUPPLY VOLTAGE LIMITS
DBIAS 18 14 DA
EMAX 59 25 10 18 1
DMAX 59 60 DA
RMAX 60 61 1K
VMAX 61 25 36V
FMAX 14 18 VMAX 0.1
******
EMIN 62 25 10 18 1
DMIN 63 62 DA
RMIN 64 63 1K
VMIN 64 25 0.1
FMIN 14 18 VMIN 0.1
******************
EREF1 65 25 10 18 1
RREF1 65 66 1MEG
VREF1 66 25 5V
**********************************************************
.MODEL QPA PNP(IS=800E-18 BF=3600)
.MODEL QNA NPN(IS=800E-18 BF=3600)
.MODEL QPB PNP(IS=800E-18 BF=2220)
.MODEL QNB NPN(IS=800E-18 BF=2220)
.MODEL DA D(N=1)
.MODEL DB D(IS=100E-14)
.model smod Vswitch(ron=1m roff=300g Von=0.8 voff=0.5 )
.model smod1 Vswitch(ron=1m roff=300g Von=0.1 voff=0.01 )
.model smod2 Vswitch(ron=1m roff=300g Von=0.5 voff=0.3 )
.model smod3 Vswitch(ron=300g roff=1m Von=0.5 voff=0.3 )
**********************************************************
.ENDS COMP
*$

*
*?@ End SIMPLIS Encryption
*