* MAX5048A MACROMODEL
* ----------------------------
* Revision 1.0 3/2007
* ----------------------------
* The MAX5048A is a high speed MOSFET driver.
* ----------------------------
* Connections
*       1 = V+
*       2 = P_OUT
*       3 = N_OUT
*       4 = GND
*       5 = IN-
*       6 = IN+
*-----------------------------
**************************************************
.SUBCKT MAX5048A 1 2 3 4 5 6
X1 2 3 5 6 1 4 MAX5048AD
.ENDS MAX5048A
**************************************************

**************************************************
.SUBCKT MAX5048AD 1 99 2 3 4 5  
**************************************************
*UVLO(3.6V and 400mV hyst)
VUV 11 5 3.6V 
GUV 5 12 POLY(2) 4 11 12 5 0 1M 400U
DUV2 5 12 DA
CUV 12 5 1P
DUV1 12 13 DA
VUV1 13 5 1V
***************
*UVLO 300nS DELAY
EUV 35 5 12 5 1
RUV 35 36 10K
DUV3 36 35 DA
CUV1 36 5 38.2P
***************
CIN1 2 5 2.5P
CIN2 3 5 2.5P
VHYS 40 5 16
*IN+ (VDD/2 and 1.6V hyst)
EVDD1 15 5 4 5 0.5
GINA 5 14 POLY(3) 3 15 14 5 40 5 0 1M 0 0 0 0 0 0 100U
DINA1 5 14 DA
CINA 14 5 0.1P
DINA2 14 13 DA
***************
*IN- (VDD/2 and 1.6V hyst)
EVDD2 17 5 4 5 0.4
GINB 5 16 POLY(3) 17 2 16 5 40 5 0 1M 0 0 0 0 0 0 100U
DINB1 5 16 DA
CINB 16 5 0.1P
DINB2 16 13 DA
***************
*AND FUNC
EAND1 18 5 14 5 1
EAND2 19 5 16 5 1
EAND3 23 5 36 5 1
DAND1 20 18 DA
DAND2 20 19 DA
DAND3 20 23 DA
RAND1 13 20 1MEG
***************
*PROP DELAY
*PROP DELAY
EPR 24 5 20 5 2
RTL1 24 25 1000
T1 25 5 26 5 ZO=1000 TD=9N
RTL2 26 5 1000
VPR 21 5 0.50
GPR 5 22 POLY(2) 26 21 4 5 0 0 0 0 80U
CPR 22 5 0.8P
DPR1 5 22 DA
DPR2 22 13 DA 
GPR1 5 27 POLY(2) 22 21 27 5 0 10 100M
CPR2 27 5 0.1P
DPR3 5 27 DA
DPR4 27 13 DA
***************
*ISUP
RSUP 4 5 12.63K
***************
*OUTPUT
EMDR 28 5 POLY(2) 13 27 4 5 0 0 0 0 1 
MP1 1 31 4 4 MP1 L=0.5U W=204U
MN1 99 32 5 5 MN1 L=0.5U W=600U
CGS1 31 5 10P
CGS2 32 5 10P
RG1 28 31 40
DG1 28 31 DB
RD2 28 32 40
DG2 32 28 DB
CL1 1 5 0.5P
CL2 99 5 0.5P
**************************************************
.MODEL MP1 PMOS(VTO=-0.7 KP=50E-6)
.MODEL MN1 NMOS(VTO=0.7 KP=100E-6)
.MODEL DA D(IS=100E-14 N=1M)
.MODEL DB D(IS=100E-14)
**************************************************
.ENDS MAX5048AD



* Copyright (c) 2003-2012 Maxim Integrated Products.  All Rights Reserved.